Motores paso a paso

Temos definidas as tres secuencias de pasos posibles. Debes comentar e descomentar segundo a que desexes usar. Lembra que no caso de usar medio paso, para dar unha volta completa necesitas o dobre número de pasos.

// Variables

const int motorPin1 = 8;    // In1
const int motorPin2 = 9;    // In2
const int motorPin3 = 10;   // In3
const int motorPin4 = 11;   // In4
                   
int motorSpeed = 1350*2;   // tempo de agarda en microsegundos
int pasosPorRevolucion = 2048;  // pasos para unha volta completa

int contador = 0;           // contador para os pasos


//Táboas de secuencia de acendido das bobinas (descomentar a que vaias usar)

//secuencia 1-fase

const int numSteps = 4;
const int pasos[4] = { B1000, B0100, B0010, B0001 };

//secuencia 2-fases

//const int numSteps = 4;
//const int pasos[4] = { B1100, B0110, B0011, B1001 };

//secuencia media fase

//const int numSteps = 8;
//const int pasos[8] = { B1000, B1100, B0100, B0110, B0010, B0011, B0001, B1001 };


// Configuración

void setup(){
  pinMode(motorPin1, OUTPUT);
  pinMode(motorPin2, OUTPUT);
  pinMode(motorPin3, OUTPUT);
  pinMode(motorPin4, OUTPUT);

  Serial.begin(9600);
}

// Función que activa as bobinas correspondentes

void setOutput(int step){
  digitalWrite(motorPin1, bitRead(pasos[step], 0));
  digitalWrite(motorPin2, bitRead(pasos[step], 1));
  digitalWrite(motorPin3, bitRead(pasos[step], 2));
  digitalWrite(motorPin4, bitRead(pasos[step], 3));
}

void loop(){

}

A librería Stepper xa vén integrada no arduino, pero só admite o método de paso completo. Se queremos máis precisión hai outras librerías, pero en principio para o que queremos facer chéganos ben con esta.

#include <Stepper.h>

const int pasosPorRevolucion = 2048;  // nº de pasos por revolución

Stepper motor(pasosPorRevolucion, 8,10,9,11);  // Iniciamos o motor paso a paso

void setup() {

  motor.setSpeed(3); // establecemos a velocidade en rpm

  Serial.begin(9600);     // Iniciamos a consola serie

}

void loop(){

}

Indicamos tamén un nome para o noso motor paso a paso e os pins aos que está conectado.

A velocidade indicámola coa instrución motor.setSpeed(5); A máis velocidade pode que non funcione, xa que estes motores necesitan un tempo mínimo entre paso e paso para activar as bobinas e xirar. Lembra que estes motores son moi precisos, pero lentos.

Neste programa facemos que o motor xire 1/4 de volta (2024/4=512) cada 2 segundos:

1. Modo manual

void loop() {
  
  for (int i = 0; i < 512; i++) {
    contador++;
    if (contador >= numSteps) {
      contador = 0;
    }
    setOutput(contador);
    delayMicroseconds(motorSpeed);
  }
  
  delay(2000);

}

2. Con librería Stepper

void loop() {

  motor.step(512);  // mover 1/4 de volta
  delay(2000);

}

Se queremos que o motor xire no sentido contrario debemos poñer o nº de pasos en negativo.

Imos facer que xire unha volta completa nun sentido, agarde 1 segundo, e xire 1 volta en sentido contrario, e así sucesivamente.

1. Modo manual

void loop() {

  // sentido horario
  
  for (int i = 0; i < pasosPorRevolucion; i++) {
    contador++;
    if (contador >= numSteps) {
      contador = 0;
    }
    setOutput(contador);
    delayMicroseconds(motorSpeed);
  }
  
  delay(1000);

  // sentido antihorario
  
  for (int i = 0; i < pasosPorRevolucion; i++){
    contador--;
    if (contador < 0) {
      contador = numSteps - 1;
    }
    setOutput(contador);
    delayMicroseconds(motorSpeed);
  } 
  
  delay(1000);
  
}

2. Con librería Stepper

void loop() {

  // unha volta nun sentido

  Serial.println("horario");

  motor.step(pasosPorRevolucion); 

  delay(1000);

  // Unha volta en sentido contrario

  Serial.println("antihorario");

  motor.step(-pasosPorRevolucion);

  delay(1000);

}

Agora imos facer que o motor xire segundo movemos un potenciómetro.

No inicio debemos definir unha variable “previous”

int previous = 0;

Cando movemos o potenciómetro o motor xirará segundo a lectura do potenciómetro

1. Modo manual

void loop() {

  int pot = analogRead(A0);

  Serial.println("pot:" + String(pot) + " - previous:" + String(previous));
  
  for (int i = 0; i < abs(pot-previous); i++) {

      if ( (pot-previous) > 0){
        contador++;
        if (contador >= numSteps) {
          contador = 0;
        }
      }
      else {
        contador--;
        if (contador < 0) {
          contador = numSteps - 1;
        }
      }
      setOutput(contador);
      delayMicroseconds(motorSpeed);
  }

  previous=pot;

  delay(100);

}

2. Con librería Stepper

void loop() {

  int pot = analogRead(0);
  
  motor.step(pot-previous);
  previous=pot;

  delay(100);

}

Neste programa imos facer que o motor se mova moi lentamente, paso a paso, e imos visualizar na consola o número de pasos que deu. Debemos empezar, no inicio do programa, definindo unha variable na que iremos rexistrando os pasos.

int contaPasos = 0;

Despois facemos que o motor xire un paso e imos engadindo os valores na variable.

1. Modo manual

void loop() {

  Serial.print("pasos:");
  Serial.println(contaPasos);

  contador++;
  if (contador >= numSteps) {
    contador = 0;
  }
  setOutput(contador);
  delayMicroseconds(motorSpeed);

  contaPasos++;
  delay(10);

}

2. Con librería Stepper

void loop() {

  motor.step(1);
  Serial.print("pasos:");
  Serial.println(contaPasos);
  contaPasos++;
  delay(10);
}